Revista do CD-ROM 101/CD-ROM 101.iso/compl/maya5ple/Install_MayaPLE5_English.exe/Maya/Data1.cab/performCreateRenderLayer.mel

Text File | 2003-07-17 | 10.7 KB | 428 lines

// Copyright (C) 1997-2002 Alias|Wavefront,
// a division of Silicon Graphics Limited.
//
// The information in this file is provided for the exclusive use of the
// licensees of Alias|Wavefront.  Such users have the right to use, modify,
// and incorporate this code into other products for purposes authorized
// by the Alias|Wavefront license agreement, without fee.
//
// ALIAS|WAVEFRONT DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
// INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
// EVENT SHALL ALIAS|WAVEFRONT BE LIABLE FOR ANY SPECIAL, INDIRECT OR
// CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
// DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
// TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
// PERFORMANCE OF THIS SOFTWARE.
//
//
//  Alias|Wavefront Script File
//  MODIFY THIS AT YOUR OWN RISK
//
//  Creation Date:  October 30, 1998
//  Author:         Socrates
//
//  Description:
//
// An option window used to create a named renderLayer.
// A renderLayer is a grouping of DAG objects used to control drawing.
//

//
//  Procedure Name:
//      setOptionVars
//
//  Description:
//        Initialize the option values.
//
//  Input Arguments:
//        Whether to set the options to default values.
//
//  Return Value:
//      None.
//
proc setOptionVars(int $forceFactorySettings)
{
    //    Render layer base index
    //
    if ($forceFactorySettings || !`optionVar -exists renderLayerBase`) {
        optionVar -intValue renderLayerBase 1;
    }

    //    Set to Current flag
    //
    if ($forceFactorySettings || !`optionVar -exists renderLayerCurrent`) {
        optionVar -intValue renderLayerCurrent false;
    }

    //    Contents flag
    //
    if ($forceFactorySettings || !`optionVar -exists renderLayerContents`) {
        optionVar -intValue renderLayerContents 1;
    }
}

//
//  Procedure Name:
//      createRenderLayerSetup
//
//  Description:
//        Update the state of the option box UI to reflect the option values.
//
//  Input Arguments:
//      parent               - Top level parent layout of the option box UI.
//                             Required so that UI object names can be
//                             successfully resolved.
//
//    forceFactorySettings - Whether the option values should be set to
//                             default values.
//
//  Return Value:
//      None.
//
global proc createRenderLayerSetup(string $parent, int $forceFactorySettings)
{
    // Retrieve the option settings
    //
    setOptionVars( $forceFactorySettings );

    // Layer name
    textFieldGrp -e -text "layer1" renderLayerNameWidget;

    // Base layer index
    int $base = `optionVar -q renderLayerBase`;
    intFieldGrp -e -v1 $base renderLayerBaseWidget;

    // Contents flag
    int $contents = `optionVar -q renderLayerContents`;
    radioButtonGrp -e -sl $contents contentsRadio;

    // Set to Current flag
    int $current = `optionVar -q renderLayerCurrent`;
    checkBoxGrp -e -v1 $current currentCheck;

    setParent $parent;
}

//
//  Procedure Name:
//      createRenderLayerCallback
//
//  Description:
//        Update the option values with the current state of the option box UI.
//
//  Input Arguments:
//      parent - Top level parent layout of the option box UI.  Required so
//               that UI object names can be successfully resolved.
//
//    doIt   - Whether the command should execute.
//
//  Return Value:
//      None.
//
global proc createRenderLayerCallback(string $parent, int $doIt)
{
    setParent $parent;

    //    Contents flag
    //
    optionVar -iv renderLayerContents `radioButtonGrp -q -sl contentsRadio`;

    //    'Make current' flag
    //
    optionVar -iv renderLayerCurrent `checkBoxGrp -q -v1 currentCheck`;

    //    Base layer index
    //
    optionVar -iv renderLayerBase `intFieldGrp -q -v1 renderLayerBaseWidget`;

    if ($doIt) {
        performCreateRenderLayer 0;
        addToRecentCommandQueue "performCreateRenderLayer 0" "CreateRenderLayer";
    }
}

//
//  Procedure Name:
//      createRenderLayerOptions
//
//  Description:
//        Construct the option box UI.  Involves accessing the standard option
//        box and customizing the UI accordingly.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//
proc createRenderLayerOptions()
{
    //    Name of the command for this option box.
    //
    string $commandName = "createRenderLayer";

    //    Build the option box actions.
    //
    string $callback = ($commandName + "Callback");
    string $setup = ($commandName + "Setup");

    //    STEP 1:  Get the option box.
    //    ============================
    //
    //    The value returned is the name of the layout to be used as
    //    the parent for the option box UI.
    //
    string $layout = getOptionBox();
    setParent $layout;

    //    STEP 2:  Pass the command name to the option box.
    //    =================================================
    //
    //    Any default option box behaviour based on the command name is set
    //    up with this call.  For example, updating the 'Help' menu item with
    //    the name of the command.
    //
    setOptionBoxCommandName($commandName);

    //    STEP 3:  Activate the default UI template.
    //    ==========================================
    //
    //    Activate the default UI template so that the layout of this
    //    option box is consistent with the layout of the rest of the
    //    application.
    //
    setUITemplate -pushTemplate DefaultTemplate;

    //    STEP 4: Create option box contents.
    //    ===================================

    //    Turn on the wait cursor.
    //
    waitCursor -state 1;

    tabLayout -tabsVisible 0 -scrollable 1;
    string $parent = `columnLayout -adjustableColumn 1`;
    string $tabForm = `columnLayout -adjustableColumn true`;

    // renderLayer name
    //
    textFieldGrp
        -label "Name"
        renderLayerNameWidget;

    // renderLayer number
    //
    intFieldGrp
        -label "Number"
        renderLayerBaseWidget;

    // Current layer setting option
    //
    checkBoxGrp -numberOfCheckBoxes 1
        -label1 "Make the created render layer current"
        currentCheck;

    // Which items to add to the layer
    //
    radioButtonGrp -nrb 3
        -cw 2 80
        -cw 4 160
        -l "Add to new render layer"
        -la3 "Nothing" "Selected" "Selected and Children"
        -sl (`optionVar -q renderLayerContents`)
        -cc1 "optionVar -iv renderLayerContents 1"
        -cc2 "optionVar -iv renderLayerContents 2"
        -cc3 "optionVar -iv renderLayerContents 3"
        contentsRadio;

    //    Turn off the wait cursor.
    //
    waitCursor -state 0;

    //    Step 5: Deactivate the default UI template.
    //    ===========================================
    //
    setUITemplate -popTemplate;

    //    Step 6: Customize the buttons.
    //    ==============================
    //
    //    Provide more descriptive labels for the buttons.  This is not
    //    necessary, but in some cases, for example, a button labelled
    //    'Create' may be more meaningful to the user than one labelled
    //    'Apply'.
    //
    //    Disable those buttons that are not applicable to the option box.
    //
    //    Attach actions to those buttons that are applicable to the option
    //    box.  Note that the 'Close' button has a default action attached
    //    to it that will hide the window.  If a a custom action is
    //    attached to the 'Close' button then be sure to call the 'hide the
    //    option box' procedure within the custom action so that the option
    //    box is hidden properly.

    //    'Apply' button.
    //
    string $applyBtn = getOptionBoxApplyBtn();
    button -edit
        -label "Create"
        -command ($callback + " " + $parent + " " + 1)
        $applyBtn;

    //    'Save' button.
    //
    string $saveBtn = getOptionBoxSaveBtn();
    button -edit
        -command ($callback + " " + $parent + " " + 0 + "; hideOptionBox")
        $saveBtn;

    //    'Reset' button.
    //
    string $resetBtn = getOptionBoxResetBtn();
    button -edit
        -command ($setup + " " + $parent + " " + 1)
        $resetBtn;

    //    Step 7: Set the option box title.
    //    =================================
    //
    setOptionBoxTitle("Render Layer Options");

    //    Step 8: Customize the 'Help' menu item text.
    //    ============================================
    //
    setOptionBoxHelpTag( "" );

    //    Step 9: Set the current values of the option box.
    //    =================================================
    //
    eval (($setup + " " + $parent + " " + 0));

    //    Step 10: Show the option box.
    //    =============================
    //
    showOptionBox();
}

//
//  Procedure Name:
//      createRenderLayerHelp
//
//  Description:
//        Return a short description about this command.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      string.
//
proc string createRenderLayerHelp()
{

    return
    "  Command: Create Render Layer - create a renderLayer.\n" +
    "Selection: Selected DAG objects are added to the renderLayer.";
}

//
//  Procedure Name:
//      assembleCmd
//
//  Description:
//        Construct the command that will apply the option box values.
//
//  Input Arguments:
//      None.
//
proc string assembleCmd()
{
    string $cmd;

    setOptionVars(false);

    // get the renderLayer name
    string $renderLayerName = "layer1";
    if (`textFieldGrp -exists renderLayerNameWidget`) {
        $renderLayerName = `textFieldGrp -q -text renderLayerNameWidget`;
    }

    // get the renderLayer base number
    int $renderLayerBase = `optionVar -q renderLayerBase`;

    // create the renderLayer command string
    if (0 == size($renderLayerName)) {
        $renderLayerName = "layer1";
    }
    $renderLayerName = "\"" + $renderLayerName + "\"";
    $cmd = "createRenderLayer -name " + $renderLayerName
                     + " -number " + $renderLayerBase;

    int $contents = `optionVar -q renderLayerContents`;
    int $current = `optionVar -q renderLayerCurrent`;
    if( $contents == 1 )
    {
        $cmd += " -empty";
    }
    else if( $contents == 2 )
    {
        $cmd += " -nr";
    }
    if( $current ) $cmd += " -mc";

    return $cmd;
}

//
//  Procedure Name:
//      performCreateRenderLayer
//
//  Description:
//        Perform the create render layer command using the corresponding
//        option values.  This procedure will also show the option box
//        window if necessary as well as construct the command string
//        that will invoke the createRenderLayer command with the current
//        option box values.
//
//  Input Arguments:
//      0 - Execute the command.
//      1 - Show the option box dialog.
//      2 - Return the command.
//
global proc string performCreateRenderLayer(int $action)
{
    string $cmd = "";

    switch ($action) {

        //    Execute the command.
        //
        case 0:
            //    Get the command.
            //
            $cmd = `assembleCmd`;

            //    Execute the command with the option settings.

            evalEcho($cmd);

            break;

        //    Show the option box.
        //
        case 1:
            createRenderLayerOptions;
            break;

        //    Return the command string.
        //
        case 2:
            //    Get the command.
            //
            $cmd = `assembleCmd`;
            break;
    }
    return $cmd;
}